[Terraform] 기본 개념과 기본 사용법
Terraform이란?
Terraform은 HashiCorp에서 개발한 오픈소스 인프라스트럭처 자동화 도구로, 사용자가 작성한 코드를 이용하여 인프라를 정의하고 관리하는 도구입니다. Terraform을 이용하면 서버, 네트워크, 데이터베이스, 로드 밸런서 등 다양한 인프라 자원을 선언적인 설정 파일(HCL, HashiCorp Configuration Language) 형태로 작성할 수 있으며 이 파일을 기반으로 원하는 클라우드 환경이나 온프레미스 환경에 인프라를 일관되게 구축, 변경, 버전 관리할 수 있습니다.
기존에는 인프라 구축을 위해 수동으로 수십 번의 클릭과 설정이 필요했지만 Terraform을 사용하면 한 번의 명령어 실행으로 필요한 모든 인프라를 자동으로 프로비저닝 할 수 있으며, 인프라 변경사항 역시 코드로 관리하여 사람의 실수를 줄이고 인프라 환경을 보다 안전하고 예측 가능하게 만들 수 있습니다. 또한 Terraform은 멀티 클라우드와 하이브리드 클라우드를 지원하여 AWS, Azure, GCP와 같은 퍼블릭 클라우드는 물론 VMware, Kubernetes와 같은 온프레미스 환경까지 통합적으로 관리할 수 있습니다. 또한 Module 기능을 통해 인프라 구성을 재사용 가능한 코드 블록으로 관리함으로써 대규모 인프라 관리에도 매우 효율적인 기능을 제공합니다.
무엇보다 Terraform의 강력한 장점 중 하나는 ‘플랜(plan)과 적용(apply)’ 과정이 명확히 분리되어 있어, 실제 인프라 변경 전에 예상 변경 사항을 검토할 수 있기 때문에 운영 환경에 미치는 영향을 최소화할 수 있다는 점입니다. 이러한 이유로 Terraform은 현재 많은 기업들이 인프라 운영 자동화(IaC, Infrastructure as Code) 전략의 핵심 도구로 채택하고 있으며 DevOps와 클라우드 네이티브 시대에 필수적인 기술로 자리 잡고 있습니다.
이번 문서에서는 Terraform의 기본 개념과 사용법, 그리고 실제로 Terraform을 사용하여 간단하게 Kubernetes에 deployment와 service를 생성하는 방법에 대해 알아보겠습니다.
Terraform HCL 기본 문법 (변수선언)
Terraform은 블록 구조를 사용하여 리소스, 데이터 소스, 모듈 등을 정의합니다. 블록은 특정 리소스나 설정을 나타내며 각 블록은 고유한 속성과 값을 가집니다. 블록 구조는 다음과 같은 형식을 가집니다.
# 블록 구조는 Terraform의 기본 구성 요소입니다.
블록타입 "종류" "이름" {
속성1 = 값
속성2 = 값
}
/* 예시
resource : 블록 타입
aws_instance : 리소스 종류
example : 리소스 이름
*/
resource "aws_instance" "example" {
ami = "ami-12345678"
instance_type = "t2.micro"
}
Terraform에서는 변수를 사용하여 코드의 재사용성을 높이고, 환경에 따라 다른 값을 쉽게 설정할 수 있습니다. 변수를 선언하는 방법은 다음과 같습니다.
locals {
숫자 = 123
불리언 = true
문자열 = "value"
여러줄문자열 = <<EOF
hello
world
EOF
리스트 = [1, 2, 3]
맵 = {
key1 = "value1"
key2 = "value2"
}
}
# 변수 선언
variable "instance_count" {
type = number
default = 3
}
# 변수 사용
output "instance_count" {
value = var.instance_count
}
Terraform HCL 기본 문법 (if, for)
Terraform에서는 조건문과 반복문을 사용하여 코드의 가독성을 높이고, 재사용성을 높일 수 있습니다.
# if문
variable "is_production" {
type = bool
default = false
}
output "env_name" {
value = var.is_production ? "production" : "development"
}
# if AND 연산
variable "is_enabled" {
type = bool
default = true
}
variable "is_ready" {
type = bool
default = true
}
output "service_status" {
value = var.is_enabled && var.is_ready ? "RUNNING" : "STOPPED"
}
# if OR 연산
variable "is_weekend" {
type = bool
default = false
}
variable "is_holiday" {
type = bool
default = true
}
output "is_day_off" {
value = var.is_weekend || var.is_holiday ? "YES" : "NO"
}
# for문
output "uppercase_fruits" {
value = [for fruit in ["apple", "banana", "cherry"] : upper(fruit)]
}
# for + if 문
output "even_numbers" {
value = [for n in [1,2,3,4,5] : n if n % 2 == 0]
}
Terraform 코드 구조
Terraform 코드는 선언적 언어로 작성되며, 각 블록은 특정 리소스나 설정을 정의합니다. Terraform 코드는 일반적으로 다음과 같은 구조로 작성됩니다.
| 블록 타입 | 설명 | 비고 |
| provider | 클라우드 provider 설정 | AWS, GCP, Azure, Kubernetes 등 클라우드 제공자에 대한 설정을 정의합니다. |
| resource | 리소스 생성 | provider에 따라 실제 인프라 리소스를 생성하는 데 사용됩니다. |
| variable | 변수 선언 | 코드에서 사용할 변수를 선언하여 재사용성을 높입니다. |
| output | 결과 출력 | Terraform 실행 후 출력할 값을 정의합니다. |
| module | 코드 재사용 | 다른 Terraform 코드에서 재사용할 수 있는 모듈을 정의합니다. |
| data | 외부 데이터 읽기 | 외부 데이터 소스에서 데이터를 읽어오는 데 사용됩니다. |
| locals | 임시 변수 | 코드 내에서 사용할 임시 변수를 정의합니다. |
| terraform | Terraform 기본 설정 | backend, provider와 같은 필수적인 값을 설정합니다. |
| backend | 상태 저장소 설정 | Terraform 상태 파일을 저장할 위치를 설정합니다. |
| provisioner | 서버 초기 작업 | 서버 생성 후 초기 작업을 수행하는 데 사용됩니다. 서버에 소프트웨어를 설치하거나 설정 파일을 복사하는 등의 작업을 수행합니다. |
Terraform 파일명 규칙
Terraform 파일은 일반적으로 `.tf` 확장자를 사용합니다. 여러 개의 파일로 구성된 Terraform 프로젝트에서는 다음과 같은 규칙을 따릅니다. 꼭 파일명을 지키지 않아도 되지만, 가독성을 높이기 위해 다음과 같은 규칙을 따르는 것이 좋습니다.
- main.tf : 주요 리소스 및 설정을 정의하는 파일
- variables.tf : 변수 선언을 포함하는 파일
- outputs.tf : 출력 값을 정의하는 파일
- locals.tf : 로컬 변수를 정의하는 파일
- provider.tf : 클라우드 제공자 설정을 포함하는 파일
- terraform.tfvars : 변수 값을 정의하는 파일
Terraform 파일들
- terraform.tfvars : 변수 값을 정의하는 파일
- terraform.tfstate : Terraform 상태 파일
- terraform.tfstate.backup : Terraform 상태 파일 백업Terraform은 상태 파일을 사용하여 현재 인프라의 상태를 관리합니다. 상태 파일은 Terraform이 관리하는 리소스의 현재 상태를 저장하며, 이를 통해 Terraform은 리소스의 변경 사항을 추적하고 관리합니다. 상태 파일은 기본적으로 `terraform.tfstate`라는 이름으로 생성됩니다. 상태 파일은 JSON 형식으로 저장되며, Terraform이 관리하는 모든 리소스의 정보를 포함합니다. 상태 파일은 Terraform이 리소스를 생성, 수정, 삭제할 때마다 업데이트됩니다.
Terraform CLI 명령어
Terraform CLI는 Terraform을 사용하여 인프라를 관리하는 데 필요한 다양한 명령어를 제공합니다. 주요 명령어는 다음과 같습니다.
# Terraform 초기화
# 디렉토리에 tf 파일을 읽어서 필요한 provider를 다운로드합니다.
# backend 설정을 읽어서 상태 파일을 저장할 위치를 설정합니다.
terraform init
# Terraform 코드 문법 검사
# 실제로 리소스를 생성하지 않고, 코드 문법을 검사합니다.
terraform validate
# Terraform 계획
# Terraform 코드에 따라 어떤 리소스가 생성될지 계획을 세웁니다.
# 실제로 리소스를 생성하지 않고, 어떤 리소스가 생성될지 계획을 세웁니다.
terraform plan
# Terraform 적용
# Terraform 계획에 따라 실제로 리소스를 생성합니다.
# -auto-approve : 자동으로 승인합니다.
terraform apply
# Terraform 상태 확인
# 현재 Terraform 상태를 확인합니다.
terraform show
# Terraform 리소스 삭제
# Terraform 코드에 따라 생성된 리소스를 삭제합니다.
terraform destroy
# Terraform 스타일 가이드에 맞게 자동 정렬합니다.
# 코드의 가독성을 높이고, 일관성을 유지하는 데 도움이 됩니다.
# -recursive : 하위 디렉토리까지 재귀적으로 적용합니다.
terraform fmt
# Terraform 출력 값 확인
terraform output
# Terraform 상태 목록 확인
terraform state list
terraform state show
실습 예제 (on Minikube)
간단한 실습을 위해 Minikube를 사용하여 Kubernetes 클러스터를 로컬에서 실행하고, Terraform을 사용하여 Kubernetes에 Deployment와 Service를 생성하는 방법을 알아보겠습니다.
실습은 Minikube로 Kubernetes 클러스터가 동작하고 있다는 가정하에 진행하였으며 아래 파일들은 모두 같은 디렉토리에 존재하여야 합니다.
provider.tf
terraform init을 수행하면 설정한 provider를 설정한 버전으로 설치합니다.
# 테라폼 설정 파일
# 이 파일은 Kubernetes 클러스터에 대한 테라폼 설정을 포함합니다.
terraform {
required_providers {
kubernetes = {
source = "hashicorp/kubernetes"
version = "~> 2.20"
}
}
}
# Kubernetes provider 설정
# ~/.kube/config 파일을 사용하여 kubernetes provider 설정
provider "kubernetes" {
config_path = "~/.kube/config"
}
variables.tf
variable로 변수를 선언하면 모든 파일에서 사용할 수 있습니다.
variable "nginx_image" {
description = "nginx 컨테이너 이미지 (태그 포함)"
type = string
default = "nginx:latest"
}
variable "nginx_nodeport" {
description = "NodePort 서비스에 사용할 포트 번호"
type = number
default = 30080
}
terraform.tfvars
variable로 선언된 값이 값을 할당할 수 있습니다.
nginx_image = "nginx:1.25.2"
nginx_nodeport = 30081
namespace.tf
kubernetes의 namespace를 생성합니다.
resource "kubernetes_namespace" "example" {
metadata {
name = "test-namespace"
}
}
deployment.tf
kubernetes의 deployment를 생성합니다.
resource "kubernetes_deployment" "nginx" {
metadata {
name = "nginx-deployment"
namespace = kubernetes_namespace.example.metadata[0].name
labels = {
app = "nginx"
}
}
spec {
replicas = 2
selector {
match_labels = {
app = "nginx"
}
}
template {
metadata {
labels = {
app = "nginx"
}
}
spec {
container {
name = "nginx"
image = var.nginx_image
port {
container_port = 80
}
}
}
}
}
}
service.tf
kubernetes의 service를 생성합니다.
resource "kubernetes_service" "nginx" {
metadata {
name = "nginx-service"
namespace = kubernetes_namespace.example.metadata[0].name
}
spec {
selector = {
app = "nginx"
}
port {
port = 80
target_port = 80
node_port = var.nginx_nodeport
}
type = "NodePort"
}
}
실습 실행
# 테라폼을 초기화합니다.
terraform init
# 테라폼이 잘 작성되었는지 검증합니다.
terraform validate
# 테라폼이 앞으로 어떻게 리소스를 생성할 것인지 확인합니다.
terraform plan
# 실제로 리소스를 생성합니다.
# -auto-approve 옵션이 없으면 리소스 배포를 동의하도록 yes를 입력해야 합니다. 현업에서는 잘 사용하지 않습니다.
terraform apply -auto-approve
# 파드가 잘 떳는지 확인
kubectl get all -n test-namespace
# 출력 결과
NAME READY STATUS RESTARTS AGE
pod/nginx-deployment-7f9c745664-whvzk 1/1 Running 0 6m55s
pod/nginx-deployment-7f9c745664-wnm87 1/1 Running 0 6m55s
NAME TYPE CLUSTER-IP EXTERNAL-IP PORT(S) AGE
service/nginx-service NodePort 10.107.11.247 <none> 80:30081/TCP 6m56s
NAME READY UP-TO-DATE AVAILABLE AGE
deployment.apps/nginx-deployment 2/2 2 2 6m55s
NAME DESIRED CURRENT READY AGE
replicaset.apps/nginx-deployment-7f9c745664 2 2 2 6m55s
# 테스트가 끝났다면 아래와 같이 생성된 리소스를 삭제합니다.
terraform destroy -auto-approve